Arduino UNO R4で、RTCをNTPから取得した時刻に設定する

#include "WiFiS3.h"
#include "RTC.h"

// 無線LAN接続情報は別ファイルに移した
#include "arduino_secrets.h"
char ssid[] = _SSID;
char pass[] = _PASS;

// NTPアクセス関係
char ntpServer[] = "pool.ntp.org";
int ntpPort = 123;

// 送受信用バッファの用意
const int NTP_PACKET_SIZE = 48;
byte buffer[NTP_PACKET_SIZE];

// クライアントのインスタンスの生成
WiFiUDP client;

void setup(){
  // シリアルインターフェイスの初期化
  Serial.begin(9600);
  delay(1000);

  // WiFiモジュールの存在確認
  if(WiFi.status() == WL_NO_MODULE){
    Serial.println("WiFiモジュールがありません");
    while(true);
  }

  // WiFiファームウェアバージョンの確認
  String fv = WiFi.firmwareVersion();
  if(fv < WIFI_FIRMWARE_LATEST_VERSION){
    Serial.println("ファームウェアが最新のものではありません");
  }

  // 無線LANへの接続
  Serial.print("接続中...");
  while(true){
    if(WiFi.begin(ssid, pass) == WL_CONNECTED)break;
    Serial.print(".");
    delay(1000);
  }
  Serial.println("完了");

  // Arduinoに割り当てられたIPアドレスの確認
  Serial.print("IPアドレス：");
  Serial.println(WiFi.localIP().toString());

  // UDPポートを開く
  client.begin(ntpPort);

    // NTPサーバに対してリクエストを送信
  memset(buffer, 0, NTP_PACKET_SIZE);
  buffer[0] = 0b00001011;
  client.beginPacket(ntpServer, ntpPort);
  client.write(buffer, NTP_PACKET_SIZE);
  client.endPacket();

  // NTPサーバからのレスポンスを受信
  unsigned long transTime;
  while(true){
    if(client.parsePacket()){
      client.read(buffer, NTP_PACKET_SIZE);
      // 時刻(Transmit Timestamp)の取得
      transTime = buffer[40]<<24 | buffer[41]<<16 | buffer[42]<<8 | buffer[43];
      break;
    }
  }

  // RTC開始と時刻の設定
  RTC.begin();
  unsigned long unixTime = transTime - 2208988800L + 32400L;
  RTCTime time(unixTime);
  RTC.setTime(time);
}

void loop(){
  // 時刻の取得
  RTCTime currentTime;
  RTC.getTime(currentTime);

  char buffer[20];
  sprintf(buffer,"%04d/%02d/%02d %02d:%02d:%02d",
    currentTime.getYear(), ((int)currentTime.getMonth())+1, currentTime.getDayOfMonth(),
    currentTime.getHour(), currentTime.getMinutes(), currentTime.getSeconds());
  Serial.println(buffer);
  delay(1000);
}

  // RTC開始と時刻の設定
  RTC.begin();
  unsigned long unixTime = transTime - 2208988800 + 32400;
  RTCTime time(unixTime);
  RTC.setTime(time);

  unsigned long unixTime = transTime - 2208988800L + 32400L;

  RTCTime time(unixTime);
  RTC.setTime(time);