Arduino UNO R4 WiFiをクライアントにする・httpsの場合

#include "WiFiS3.h"

// 無線LAN接続情報は別ファイルに移した
#include "arduino_secrets.h"
char ssid[] = _SSID;
char pass[] = _PASS;

// 接続先の情報
char host_name[] = "www.google.com";
int  host_port   = 443;
char host_file[] = "/";

// クライアントのインスタンスの生成
WiFiSSLClient client;

void setup(){
  // シリアルインターフェイスの初期化
  Serial.begin(9600);
  delay(1000);

  // WiFiモジュールの存在確認
  if(WiFi.status() == WL_NO_MODULE){
    Serial.println("WiFiモジュールがありません");
    while(true);
  }

  // WiFiファームウェアバージョンの確認
  String fv = WiFi.firmwareVersion();
  if(fv < WIFI_FIRMWARE_LATEST_VERSION){
    Serial.println("ファームウェアが最新のものではありません");
  }

  // 無線LANへの接続
  Serial.print("接続中...");
  while(true){
    if(WiFi.begin(ssid, pass) == WL_CONNECTED)break;
    Serial.print(".");
    delay(1000);
  }
  Serial.println("完了");

  // Arduinoに割り当てられたIPアドレスの確認
  Serial.print("IPアドレス：");
  Serial.println(WiFi.localIP().toString());

  if(client.connect(host_name, host_port)){
    // サーバにリクエストを送信
    char sendBuffer[128];
    sprintf(sendBuffer, "GET %s HTTP/1.1\r\nHost: %s\r\n\r\n", host_file, host_name);
    client.print(sendBuffer);
  }
  while(true){
    while(client.available()){
      // サーバからのデータを受信
      char c = client.read();
      Serial.print(c);
    }
    if(!client.connected()){
      // サーバ側から切断されたら終了
      Serial.println("disconnected");
      client.stop();
      break;
    }
  }
}

void loop() {

}

// 接続先の情報
char host_name[] = "www.google.com";
int  host_port   = 443;
char host_file[] = "/";

// クライアントのインスタンスの生成
WiFiSSLClient client;